/********************************************************************************************************************************************
//Macros for TRIMMER T18 by Vishay
//Designed by Philippe Boucheny <philippe.boucheny(replace with at)free.fr>
//Rev. 1.0 29/12/05
********************************************************************************************************************************************/
#macro RES_DIS_TRIM_T18_GRND (value)
union{
#local VishayBlue=color red 0.0 green 0.4453 blue 0.73;
    difference{
        cylinder{<-8.25,4.8,0> <-9.75,4.8,0> 1.25}
        box{<-9.15,5.1,-2><-10,4.5,+2>}   
        texture {T_Brass_2A}
    }
    difference{
        box{<-8.25,0,-2.35><+10.75,+6.4,+2.35>}  // case
        box{<-8.25+0.8,-0.1,-2.36><+10.75-0.8,+0.5,+2.36>}       
        pigment{VishayBlue}
    }
    #local hpin=-min(4.5,(pin_length+pcb_hight));
    
    difference{
        union{
            prism {0 0.2 5 <-0.5,+0.5>,<-0.1,-5>,<+.1,-5>,<+0.5,+0.5>,<-0.5,+0.5> rotate -90*x translate 1.27*z pigment{Silver}}                
            prism {0 0.2 5 <-0.5,+0.5>,<-0.1,-5>,<+.1,-5>,<+0.5,+0.5>,<-0.5,+0.5> rotate -90*x translate <-5.1,0,-1.27> pigment{Silver}}                
            prism {0 0.2 5 <-0.5,+0.5>,<-0.1,-5>,<+.1,-5>,<+0.5,+0.5>,<-0.5,+0.5> rotate -90*x translate <+7.6,0,-1.27> pigment{Silver}}           
        }
        box{<-10,hpin,-3><+10,-10,+3>pigment{Silver}}
    }     

    union{
    	text {ttf "Arial.ttf" "T18" 0.1, 0 scale 2 rotate<90,180,0> translate<+8,6.45,-0.4>}
    	text {ttf "Arial.ttf" value 0.1, 0 scale 2 rotate<90,180,0> translate<+8,6.45,+1.6>}
    	text {ttf "Arial.ttf" "3" 0.1, 0 scale 2 rotate<90,180,0> translate<-5,6.45,-0.4>}
    	text {ttf "Arial.ttf" "0302" 0.1, 0 scale 2 rotate<90,180,0> translate<-1.8,6.45,+1.6>}
    	text {ttf "Normes.ttf" "0" 0.1, 0 scale 2 rotate<90,180,0> translate<+2,6.45,-0>}
        pigment{Black}
    }
    rotate 180*y
}
#end

#macro RES_DIS_TRIM_T18(value)
object{RES_DIS_TRIM_T18_GRND(value)}
#end